■ はじめに

Terraform の 変数について扱う。

【０】Terraform の変数

* 以下の２種類。
~~~~
１）ローカル変数 - local
２）変数 - variable
~~~~

* 以下のサイト、すごくいい記事、、、

https://zenn.dev/sway/articles/terraform_biginner_varliable

* 変数については、以下の関連記事を参照

Terraform ～ variable / 入門編～
https://dk521123.hatenablog.com/entry/2025/09/19/093537

【１】local

* ローカル変数の定義
 => locals セクションで定義

https://developer.hashicorp.com/terraform/language/values/locals

【２】Hello world

locals.tf (ローカル変数の定義)

locals {
  content  = "hello world!!!?"
  filename = "hello.txt"
}

main.tf (呼び出し元)

# ローカル変数の参照
resource "local_file" "helloworld" {
  # local.<key>で参照できる
  content  = local.content
  # ${local.<key>}でも参照できる（文字列連結時に使える）
  filename = "${local.filename}"
}

【３】List

* 以下の関連記事で使用

https://dk521123.hatenablog.com/entry/2025/09/18/003116

locals.tf (ローカル変数の定義)

# 対象の既存バケット名リスト
locals {
  s3_buckets = [
    "your-existing-bucket-a",
    "your-existing-bucket-b",
    "your-existing-bucket-c"
  ]
}

s3.tf (呼び出し元)

# 既存バケットをデータソースでまとめて参照
data "aws_s3_bucket" "target" {
  for_each = toset(local.s3_buckets)
  bucket   = each.value
}

# Lambdaへのinvoke権限 (for_eachで全バケット分)
resource "aws_lambda_permission" "allow_s3" {
  for_each = data.aws_s3_bucket.target

  statement_id  = "AllowExecutionFromS3-${each.key}"
  action        = "lambda:InvokeFunction"
  function_name = aws_lambda_function.s3_event.function_name
  principal     = "s3.amazonaws.com"
  source_arn    = each.value.arn
}

# S3イベント通知 → Lambda (for_eachで全バケット分)
resource "aws_s3_bucket_notification" "notify" {
  for_each = data.aws_s3_bucket.target

  bucket = each.value.id

  lambda_function {
    lambda_function_arn = aws_lambda_function.s3_event.arn
    events              = ["s3:ObjectCreated:*", "s3:ObjectRemoved:*"]
  }

  depends_on = [ aws_lambda_permission.allow_s3 ]
}